Altera DE0 - Nano開發 ADC應用

-
前言：
    最近因為做實驗的關係，作者接觸了Altera DE0-nano開發版，發現這個板子雖然小小一塊但功能卻很齊全的，包含了加速計、8個led燈示、四段指撥開關、兩個復歸按鈕、8通道12bitADC以及多達80個GPIO(裡面涵蓋Vcc及Gnd)可以去使用，而本文章是使用其ADC讀取感測器數值的應用本文章是使用其ADC讀取感測器數值的應用

    下圖為板子的正反面照片，ADC位置在背面(圖b)
                                       圖a. 正面照                                   圖b. 背面照
圖c. Pin腳圖
    DE0-Nano使用的ADC晶片為ADC128S022，其通訊使用的是SPI進行資料交換如下圖所示
圖d. ADC128S022 Serial Timing Diagram
    依據圖d的通訊圖可以看出當CS Low時，其SCLK以16個為一組DATA的資料，為了配合撰寫程式，本文章以0至15來取代1至16，其中資料的第0個與第1個不列入參考，而第2~4為選擇ADC Channel的Address(由Din腳為提供)，最後第4~15為晶片所量測到的電壓數位訊號(由Dout送出)，其訊號範圍為0~3.3伏特(數位訊號為0~4095)。

實作：
    SCLK： 
library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;

entity Divider100 is
 generic (
  CLK_DIV : integer := 100
 );
 port(
  reset: in std_logic;
  CLK : in std_logic;
  enable : in std_logic;
  SCLK_RISING : out std_logic;
  SCLK_FALLING : out std_logic
 );
end Divider100;

architecture arch of Divider100 is
 signal sclk_r, sclk_f : std_logic;
 signal counter : integer range 0 to CLK_DIV;
begin
 process(CLK, reset)
 begin
  if(reset = '0') then
   sclk_r <= '0';
   sclk_f <= '0';
   counter <= 0;
  elsif(rising_edge(CLK)) then
   if(enable = '1') then
    if(counter = ((CLK_DIV/2)-1)) then
     sclk_r <= '0';
     sclk_f <= '1';
     counter <= counter+1;
    elsif(counter = (CLK_DIV-1)) then
     sclk_r <= '1';
     sclk_f <= '0';
     counter <= 0;
    else
     sclk_r <= '0';
     sclk_f <= '0';
     counter <= counter+1;
    end if;
   else
    sclk_r <= '0';
    sclk_f <= '0';
    counter <= 0;
   end if;
  end if;
 end process;
 SCLK_RISING <= sclk_r;
 SCLK_FALLING <= sclk_f;
 
end arch;
    SPI_Out 
library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;

entity SPI_Out is
 port(
  reset : in std_logic;
  CLK : in std_logic;
  enable : in std_logic;
  update :in std_logic;
  dataStep :in integer;
  pinSelect : in std_logic_vector(2 downto 0);
  divider_r: in std_logic;
  divider_f: in std_logic;
  SPI_CS : out std_logic;
  SPI_MOSI : out std_logic;
  SPI_SCLK : out std_logic
 );
end SPI_Out;

architecture arch of SPI_Out is
 signal outputTemp : std_logic_vector(2 downto 0);
begin
 process(CLK, reset)
 begin
  if(reset = '0') then
   outputTemp <= (others=>'0');
   SPI_CS <= '1';
   SPI_MOSI <= '1';
   SPI_SCLK <= '1';
  elsif(rising_edge(CLK)) then
   SPI_CS <= not enable;
   if(update = '1') then
    outputTemp <= pinSelect;
   end if;
   if(enable = '1') then
    if(divider_r = '1') then
     SPI_SCLK <= '1';
    elsif(divider_f = '1') then
     SPI_SCLK <= '0';
    end if;
   else
    SPI_SCLK <= '1';
   end if;
   if(divider_f='1') then
    case dataStep is
     when  2  => SPI_MOSI <= outputTemp(2);
     when  3  => SPI_MOSI <= outputTemp(1);
     when  4  => SPI_MOSI <= outputTemp(0);
     when others => NULL;
    end case;
   end if;
  end if;
 end process;
end arch;
    SPI_In 
library ieee;
use ieee.std_logic_1164.all;

entity SPI_in is
 port(
  reset : in std_logic;
  CLK : in std_logic;
  dataStep :in integer;
  update :in std_logic;
  SPI_MISO : in std_logic;
  dataOutput : out std_logic_vector(11 downto 0)
 );
end SPI_In;

architecture arch of SPI_In is
 signal misoSignal : std_logic;
 signal outputTemp : std_logic_vector(11 downto 0);
begin
 process(CLK,reset)
 begin
  if(reset = '0') then
   misoSignal <= '0';
   outputTemp <= (others=>'0');
  elsif(rising_edge(CLK)) then
   misoSignal <= SPI_MISO;
   if(update = '1') then 
    dataOutput <= outputTemp;
   end if;
   case dataStep is
    when  4  => outputTemp(11)  <= misoSignal;
    when  5  => outputTemp(10)  <= misoSignal;
    when  6  => outputTemp( 9)  <= misoSignal;
    when  7  => outputTemp( 8)  <= misoSignal;
    when  8  => outputTemp( 7)  <= misoSignal;
    when  9  => outputTemp( 6)  <= misoSignal;
    when 10  => outputTemp( 5)  <= misoSignal;
    when 11  => outputTemp( 4)  <= misoSignal;
    when 12  => outputTemp( 3)  <= misoSignal;
    when 13  => outputTemp( 2)  <= misoSignal;
    when 14  => outputTemp( 1)  <= misoSignal;
    when 15  => outputTemp( 0)  <= misoSignal;
    when others => NULL;
   end case;
   
  end if;
 end process;
end arch;
    SPI_Master 
library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;
use work.Bus_Declare.all;

entity SPI_ADC_Master is
 port(
  CLK : in std_logic;
  reset : in std_logic;
  enable : in std_logic;
  SPI_MISO : in std_logic;
  SPI_MOSI : out std_logic;
  SPI_CS : out std_logic;
  SPI_SCLK : out std_logic;
--  outputLed : out std_logic_vector(7 downto 0);
  dataOutput : out bus_array_12(7 downto 0)
 );
end SPI_ADC_Master;

architecture arch of SPI_ADC_Master is
 signal outputTemp : bus_array_12(7 downto 0) := (others => (others => '0'));
 signal dataStream : std_logic_vector(11 downto 0);
 signal updateSignal : std_logic;
 signal sclk_r_Signal : std_logic;
 signal sclk_f_Signal : std_logic;
 signal dataStepSignal : integer;
 signal pinSelect : std_logic_vector(2 downto 0);
 signal tempCount : integer := 0;
 component Divider100 is
  port(
   reset: in std_logic;
   CLK : in std_logic;
   enable : in std_logic;
   SCLK_RISING : out std_logic;
   SCLK_FALLING : out std_logic
  );
 end component;
 
 component SPI_In is
  port(
   reset : in std_logic;
   CLK : in std_logic;
   dataStep :in integer;
   update :in std_logic;
   SPI_MISO : in std_logic;
   dataOutput : out std_logic_vector(11 downto 0)
  );
 end component;
 
 component SPI_Out is
  port(
   reset : in std_logic;
   CLK : in std_logic;
   enable : in std_logic;
   update :in std_logic;
   dataStep :in integer;
   pinSelect : in std_logic_vector(2 downto 0);
   divider_r: in std_logic;
   divider_f: in std_logic;
   SPI_CS : out std_logic;
   SPI_MOSI : out std_logic;
   SPI_SCLK : out std_logic
  );
 end component;
 
 component StepCounter is
  port(
   reset : in std_logic;
   CLK : in std_logic;
   enable : in std_logic;
   update : out std_logic;
   divider_r: in std_logic;
   divider_f: in std_logic;
   dataStep : out integer
  );
 end component;
begin
 DIVIDER: Divider100 port map(reset, CLK, enable, sclk_r_Signal, sclk_f_Signal);
 SPIIn : SPI_In port map(reset, CLK, dataStepSignal, updateSignal, SPI_MISO, dataStream);
 SPIOut : SPI_Out port map (reset, CLK, enable, updateSignal, dataStepSignal, pinSelect, sclk_r_Signal, sclk_f_Signal, SPI_CS, SPI_MOSI, SPI_SCLK);
 STEPCOUNT : StepCounter port map(reset, CLK, enable, updateSignal, sclk_r_Signal, sclk_f_Signal, dataStepSignal);

 
 process(CLK, reset)
  constant pinCount : integer := 7;
 begin
  if(reset = '0') then
   tempCount <= 0;
   pinSelect <= "000";
   outputTemp <= (others => (others => '0'));
  elsif(rising_edge(CLK)) then
   if(enable = '1') then
    if(updateSignal = '1') then
     outputTemp(tempCount) <= dataStream;
     case tempCount is
      when  4  => pinSelect <= "000";
      when  5  => pinSelect <= "001";
      when  6  => pinSelect <= "010";
      when  7  => pinSelect <= "011";
      when  0  => pinSelect <= "100";
      when  1  => pinSelect <= "101";
      when  2  => pinSelect <= "110";
      when  3  => pinSelect <= "111";
      when others => NULL;
     end case;
     
     if(tempCount < pinCount) then
      tempCount <= tempCount + 1;
     else
      tempCount <= 0;
     end if;
    end if;
   else
    pinSelect <= "000";
    outputTemp <= (others => (others => '0'));
    tempCount <= 0;
   end if;
  end if;
 end process;
 
 dataOutput <= outputTemp;
end arch;
    根據SPI_ADC模組中Channel0~Channel7皆會去掃描後將各個channel數值記錄在暫存器中，而下一章會教如何將數值傳出做應用

留言

張貼留言

這個網誌中的熱門文章

Python-相關係數矩陣實作(python-correlation matrix )

-
圖片
相關係數被用來 用於度量兩個變數X和Y之間的相關 程度（線性相依），其值介於-1與1之間。在自然科學領域中，該係數廣泛用於度量兩個變數之間的線性相依程度。 再資料科學中，前處理步驟可先用來觀察參數間的關係，可幫助找到對目標參數影響較大的變數。 下面就用python實作係數矩陣視覺化。 import pandas as pd import matplotlib.pyplot as mp, seaborn #讀資料 xls_file = pd.ExcelFile('A.xlsx') df = xls_file.parse('sheet1') data=df print(df) #視覺化 df_corr = df.corr() seaborn.heatmap(df_corr, center=0, annot=True) mp.show() dataframe長這樣 相關係數矩陣
閱讀完整內容

ASP.NET-後端將值傳給javascript

-
這邊介紹兩個基礎但很常會用到的技巧。 首先要如後將後端的值傳給前端的javascript。 首先在前端(aspx)設一個HiddenField物件 <asp:HiddenField ID="hf_time" runat="server" /> 後端(aspx.cs)給值 hf_time.Value = "TEST"; 前端(aspx)javascript取值         <script type="text/javascript">             function getValue {                 var value = document.getElementById("<%=hf_time.ClientID%>").value;             }         </script> 再來是進階應用，按鈕點擊呼叫jquery的blockUI並且顯示特定值。 上個階段有的東西這邊都要另外再拉一個button的物件。 <asp:Button ID="btn_test" class="genbtn" runat="server" Text="測試" OnClick="btn_test_Click" OnClientClick="markpage1();" /> 可以看到在按下按鈕時前端會去呼叫markpage1()這個function，接下來就是在javascript寫這個function。         <script type="text/javascript" src="../js/jquery.blockUI.js"></script>         <script type="text/javascript"> ...
閱讀完整內容

ASP.NET-FileUpload上傳後自動觸發button click(FileUpload upload auto trigger button click)

-
在ASP.NET中FileUpload很常都需要配一個button，上傳檔案一個動作，上傳後還需點擊按鈕才能觸發後續的儲存等等功能。 這邊要實作上傳檔案後自動觸發後續功能，不用再多一步點擊按鈕。 前端: 當fileUpload的值不為空自動找到button做click動作     <script type="text/javascript">     function UploadFile(fileUpload) {         if (fileUpload.value != '') {             document.getElementById("<%=btn_upload.ClientID %>").click();         }     }     </script> 新增FileUpload跟button並把button隱藏 <asp:FileUpload ID="FileUpload1" runat="server" /> <asp:Button ID="btn_upload" runat="server" OnClick="btn_upload_Click" Style="display: none" /> 後端: using System.IO; //新增屬性當onchange時觸發javascript function protected void Page_Load(object sender, EventArgs e) {       FileUpload1.Attributes["onchange"] = "UploadFile(this)";        } //完成自動觸發button click protected void btn_upload_Click(object sender, EventArgs e)...
閱讀完整內容